#define make_donut_model
/** \file donut.gml
 * A script to generate a horizontal ring torus model 
 * with normals and a texture
 * 22 July 2006
 */

/** \def make_donut_model(radius,radius2,steps,steps2)
 * make_donut_model(radius,radius2,steps,steps2)
 *
 * radius is the radius of the torus
 * radius2 is the radius of the cross-section
 * so that the total outside radius=radius+radius2
 * and the radius of the hole=radius-radius2 
 * steps=the number of segments round the torus (try 20)
 * steps2=the number of steps through the hole (try 10)
 *
 * returns a model ID
 *
 * Model is generated as a series of triangle_strips so the vertex
 * count is almost half that of a triangle_list form
 * Model has been tweaked so the texture wraps onto the torus in 
 * a similar way to the basic sphere.
 * 
 */
var donut_ID0,dx,dx2,dy,xs,ys,r,r2,tx,ty,tz,tx2,ty2,tz2,tx3,ty3,tz3,tx4,ty4,tz4;
donut_ID0 = d3d_model_create();
r=argument0;
r2=argument1;
xs=floor(argument2);
ys=floor(argument3);
for(dx=0;dx<xs;dx+=1)
{
  dx2=(dx+1) mod xs;
  d3d_model_primitive_begin(donut_ID0,pr_trianglestrip);
  tx=cos(dx*pi*2/xs);
  ty=sin(dx*pi*2/xs);
  tz=0;
  tx2=cos(dx2*pi*2/xs);
  ty2=sin(dx2*pi*2/xs);
  tz2=0;
  
  for(dy=0;dy<=ys;dy+=1)
  {
    tx3=-tx*cos(dy*pi*2/ys);
    ty3=-ty*cos(dy*pi*2/ys);
    tz3=sin(dy*pi*2/ys);
    tx4=-tx2*cos(dy*pi*2/ys);
    ty4=-ty2*cos(dy*pi*2/ys);
    tz4=sin(dy*pi*2/ys);
    d3d_model_vertex_normal_texture(donut_ID0,tx2*r+tx4*r2,ty2*r+ty4*r2,tz2*r+tz4*r2,tx4,ty4,tz4,(dx+1)/xs,dy/ys);
    d3d_model_vertex_normal_texture(donut_ID0,tx*r+tx3*r2,ty*r+ty3*r2,tz*r+tz3*r2,tx3,ty3,tz3,dx/xs,dy/ys);
  };
  d3d_model_primitive_end(donut_ID0);
};

return donut_ID0;